【オリジナル理論で拡張現実センサを作ってみよう】

【HTML5+JavaScript+AR】【円形マーカー検出拡張現実センシング】

【以下は過去記事の残骸です。最新版は上記記事URLにて記載】

【ARToolKitの中身の処理を考察してみる】

【太線枠抽出で用いた高速フィルタ：矩形波相関トリガ法】

【メインの一部】

  Nx = MyPic1.Header.Nx
  Ny = MyPic1.Header.Ny
  BuildBitMap Nx, Ny, MyPic2 '【MyPic2を作成】
  BuildBitMap Nx, Ny, MyPic3 '【MyPic3を作成】
  nScan = 0
  ReDim XL(Ny - 1), XR(Ny - 1)
  
  For j = 0 To Ny - 1
     initFilter '【フィルタ初期化】
     For i = 0 To Nx - 1
        P = Filter(MyPic1, i, j)
        DrawPixel MyPic2, i, j, P
     Next i
     If AR_OnFlag Then
        For i = Nx - 1 To AR_XOn Step -1
           DrawPixel MyPic2, i, j, MyPic2.White
        Next i
     End If
     If wXL >= 0 Then
        Sheet3.Cells(20 + nScan, 2) = j
        Sheet3.Cells(20 + nScan, 3) = wXL
        Sheet3.Cells(20 + nScan, 4) = wXR
        
        nScan = nScan + 1
     End If
  Next j
  CreateBitMapFile MyPic2, dFileName
  Image2.Picture = LoadPicture(dFileName)

【フィルタ部】

Private AR_SumR As Integer
Private AR_SumG As Integer
Private AR_SumB As Integer
Private AR_FIFO_R() As Integer
Private AR_FIFO_G() As Integer
Private AR_FIFO_B() As Integer
Private AR_Ptr0 As Integer
Private AR_Ptr1 As Integer
Public AR_Nw As Integer
Public AR_Nw2 As Integer
Private AR_Th As Integer
Public AR_XOn As Integer
Public AR_XOff As Integer
Public AR_OnFlag As Boolean
Private AR_J1 As Boolean '【左端エッジ】
Private AR_J2 As Boolean '【右端エッジ】
Private AR_J3 As Boolean '【ステータス】
Public wXL As Integer   '左端
Public wXR As Integer   '右端
Public nScan As Integer '検出データ数
Private XL() As Integer  '左端リスト
Private XR() As Integer  '右端リスト

Public Sub initFilter()
  Dim i As Integer
  
  AR_Nw = 10         'FIFO段数  30
  AR_Th = AR_Nw * 20 'しきい値
  AR_Nw2 = AR_Nw \ 2 '検出厚み
  AR_Ptr0 = 0        'FIFOポインタの初期化
  AR_Ptr1 = AR_Nw2   'FIFOポインタの初期化
  AR_SumR = 0
  AR_SumG = 0
  AR_SumB = 0
  ReDim AR_FIFO_R(AR_Nw - 1), AR_FIFO_G(AR_Nw - 1), AR_FIFO_B(AR_Nw - 1)
  For i = 0 To AR_Nw - 1
     AR_FIFO_R(i) = -128
     AR_FIFO_G(i) = -128
     AR_FIFO_B(i) = -128
  Next i
  AR_OnFlag = False
  AR_J1 = False
  AR_J2 = False
  AR_J3 = False
  wXL = -1
  wXR = -1
End Sub

Public Function Filter(cg As NTL_BitMap, x As Long, y As Long) As RGB24bitPixel
   Dim w0 As Integer, w1 As Integer, w2 As Integer
   Dim P As RGB24bitPixel
   
   P = GetPixel(cg, x, y)   '指定座標から画素情報を読み出す
   w0 = CInt(P.Red) - 128   'signed int(-128～127)に変換
   w1 = CInt(P.Green) - 128 ' 暗：-128
   w2 = CInt(P.Blue) - 128  ' 明：127
   AR_SumR = AR_SumR - w0 + 2 * AR_FIFO_R(AR_Ptr1) - AR_FIFO_R(AR_Ptr0)
   AR_SumG = AR_SumG - w1 + 2 * AR_FIFO_G(AR_Ptr1) - AR_FIFO_G(AR_Ptr0)
   AR_SumB = AR_SumB - w2 + 2 * AR_FIFO_B(AR_Ptr1) - AR_FIFO_B(AR_Ptr0)
   AR_FIFO_R(AR_Ptr0) = w0
   AR_FIFO_G(AR_Ptr0) = w1
   AR_FIFO_B(AR_Ptr0) = w2
   AR_Ptr0 = AR_Ptr0 + 1: If AR_Ptr0 = AR_Nw Then AR_Ptr0 = 0
   AR_Ptr1 = AR_Ptr1 + 1: If AR_Ptr1 = AR_Nw Then AR_Ptr1 = 0
   AR_J1 = (AR_SumR > AR_Th) And (AR_SumG > AR_Th) And (AR_SumB > AR_Th)    '【左端エッジ】
   AR_J2 = (-AR_SumR > AR_Th) And (-AR_SumG > AR_Th) And (-AR_SumB > AR_Th) '【右端エッジ】
   If AR_OnFlag Then '【FlagがOnのとき】
      AR_XOff = x
      wXR = x
      If AR_J3 Then '【右端エッジ検出時】
         If AR_J2 = False Then
            AR_OnFlag = False
            AR_J3 = False
         End If
      Else '【右端エッジ出現待ち】
         If AR_J2 Then
            AR_J3 = True
         End If
      End If
   Else '【FlagがOffのとき】
      If AR_J1 Then '【左端エッジ検出】
         AR_OnFlag = True
         AR_XOn = x
         AR_XOff = x
         AR_J3 = False '【右端エッジ未検出】
         If wXL = -1 Then
            wXL = x '最左端座標を記録
         End If
      End If
   End If
   If AR_OnFlag Then P = cg.Black Else P = cg.White
   Filter = P
End Function

【Hough変換って、とっても面倒そうなのでオリジナルアルゴリズムを考えてみました】

【円形マーカーのオリジナル検出アルゴリズムを考えて試作を完了】